Cách kiểm tra phiên bản của nhà cung cấp oracle cho ole-db. Nhà cung cấp OraOLEDB.Oracle

Bạn có thể sử dụng công cụ ví dụ như RegDllView. Tìm kiếm "OraOLEDB", kết quả có thể là:

Một cách tiếp cận đơn giản hơn sẽ là điều hướng đến ORACE_HOME\bin của bạn thư mục và định vị tệp OraOLEDB??.dll . Kiểm tra phiên bản bằng cách nhấp chuột phải -> Thuộc tính -> Chi tiết.

Tuy nhiên, bạn chỉ nhận được phiên bản của tệp, điều đó không nhất thiết có nghĩa là tệp DLL này cũng đã được đăng ký và sẵn sàng để sử dụng.

Hoặc sử dụng VBScript này:

Option Explicit
Const HKEY_CLASSES_ROOT = &H80000000

Dim Key, strComputer, objRegistry, strPath, arrKeys, fso
Dim strKeyPath, strValueName, strValue, uValue, ver

Set fso = CreateObject("Scripting.FileSystemObject")

strComputer = "."
Set objRegistry = GetObject("winmgmts:\\" & strComputer & "\root\default:StdRegProv")
objRegistry.enumKey HKEY_CLASSES_ROOT, "CLSID", arrKeys

For Each key In arrKeys
    strKeyPath = "CLSID\" & key
    strValueName = "OLEDB_SERVICES"
    If objRegistry.GetDWordValue (HKEY_CLASSES_ROOT, strKeyPath, strValueName, uValue) = 0 Then  
        'get the (Default) value which is the name of the provider
        objRegistry.GetStringValue HKEY_CLASSES_ROOT, strKeyPath, "", strValue
        If InStr(1, strValue, "OraOLEDB.Oracle", vbTextCompare) > 0 Then
            ' get expanded location
            objRegistry.GetStringValue HKEY_CLASSES_ROOT, strKeyPath & "\InprocServer32", "", strPath

            ver = fso.GetFileVersion(strPath)
            Wscript.Echo strValue & " @ " & strPath & " -> " & ver
        End If
    End If 
Next

Nhà cung cấp OLE DB có thể tồn tại ở 32 bit hoặc / và 64 bit, vì vậy bạn có thể thực thi tập lệnh hai lần:

C:\Windows\System32\cscript.exe Print_OLE.vbs
C:\Windows\SysWOW64\cscript.exe Print_OLE.vbs