Oracle có cung cấp cách trả về nhiều chuỗi con từ một hàng chuỗi / khối đã được phân tích cú pháp không?

Có thể như thế này:

CREATE OR REPLACE FUNCTION explode(longline varchar)
  RETURN sys.dbms_debug_vc2coll PIPELINED
IS  
  pos PLS_INTEGER;
  lastpos PLS_INTEGER;
  element varchar(2000);
BEGIN
   lastpos := 1;
   pos := instr(longline, ',');

   while pos > 0 loop
      element := substr(longline, lastpos, pos - lastpos);
      lastpos := pos + 1;
      pos := instr(longline, ',', lastpos);
      pipe row(element);
   end loop;

   if lastpos <= length(longline) then
      pipe row (substr(longline, lastpos));
   end if;

   RETURN;
END;  
/

Điều này có thể được sử dụng như thế này:

SQL> select * from table(explode('1,2,3'));

COLUMN_VALUE
---------------------------------------------
1
2
3
SQL>

Nếu bạn không sử dụng 11.x, bạn cần tự xác định kiểu trả về:

create type char_table as table of varchar(4000);

và thay đổi khai báo hàm thành:

CREATE OR REPLACE FUNCTION explode(longline varchar)
  RETURN char_table pipelined
.....