Groovy Oracle được lưu trữ Proc - chỉ mục cột ẩn

Đoạn mã sau có thể giúp bạn lấy biến của SYS_REFCURSOR từ khối ẩn danh Oracle.

Chúng ta nên tập trung vào một số chi tiết chính:

1. Lớp groovy.sql.Sql không có OutParameter tương ứng và chúng tôi đặt nó theo cách thủ công là CURSOR_PARAMETER và chuyển nó tới sql.call phương pháp
2. Hãy xem xét rằng khối bắt đầu bằng {call DECLARE và kết thúc bằng END } không có dấu chấm phẩy sau END. Nếu không, chúng tôi có thể nhận được SQLException kém nhận biết vào mặt.
3. Các dấu chấm hỏi ? bên trong sqlString là nơi cho các ràng buộc tham số. Các ràng buộc được thực hiện theo thứ tự tự nhiên lấy các giá trị từ parametersList .
   • Trong ví dụ này, chúng tôi có liên kết duy nhất, vì vậy ? liên kết với CURSOR_PARAMETER coi giá trị là OUT tham số của kiểu đã truyền;
4. Chỉ có một lần nhập để đóng sau sql.call và ResultSet rs cung cấp các hàng con trỏ my_cur được khai báo trong khối ẩn danh.
5. Chúng tôi có thể đơn giản hóa sqlString bằng cách sử dụng một hàm trả về SYS_REFCURSOR bỏ sót một thủ tục với OUT tham số. Vì vậy, nó có thể giống như thế này "{call BEGIN ? := MY_FUNC(); END}" hoặc thậm chí "{? = call MY_FUNC()}"

import groovy.sql.OutParameter
import groovy.sql.Sql
import oracle.jdbc.OracleTypes

import java.sql.ResultSet

def driver = 'oracle.jdbc.driver.OracleDriver'
def sql = Sql.newInstance('jdbc:oracle:thin:@my-server:1521:XXX', 'usr', 'psw', driver)

// special OutParameter for cursor type
OutParameter CURSOR_PARAMETER = new OutParameter() {
    public int getType() {
        return OracleTypes.CURSOR;
    }
};

// look at some ceremonial wrappers around anonymous block
String sqlString = """{call
    DECLARE
      my_cur SYS_REFCURSOR;
    BEGIN
        STORED_PROCEDURE_NAME(my_cur);
        ? := my_cur;
    END
}
""";

// the order of elements matches the order of bindings
def parametersList = [CURSOR_PARAMETER];


// rs contains the result set of cursor my_cur
sql.call(sqlString, parametersList) { ResultSet rs ->
  while (rs.next()) {
      println rs.getString("my_column")
  }
};

P.S. Và cảm ơn bạn vì câu hỏi.