Tách các giá trị được phân tách trong một cột SQL thành nhiều hàng

Nếu bạn đang sử dụng SQL Server 2016+

Bạn có thể sử dụng STRING_SPLIT mới chức năng mà tôi đã viết blog ở đây và Brent Ozar đã viết blog về đây.

SELECT s.[message-id], f.value
  FROM dbo.SourceData AS s
  CROSS APPLY STRING_SPLIT(s.[recipient-address], ';') as f;

Nếu bạn vẫn đang sử dụng phiên bản trước SQL Server 2016

Tạo một hàm chia nhỏ. Đây chỉ là một trong nhiều ví dụ:

CREATE FUNCTION dbo.SplitStrings
(
    @List       NVARCHAR(MAX),
    @Delimiter  NVARCHAR(255)
)
RETURNS TABLE
AS
    RETURN (SELECT Number = ROW_NUMBER() OVER (ORDER BY Number),
        Item FROM (SELECT Number, Item = LTRIM(RTRIM(SUBSTRING(@List, Number, 
        CHARINDEX(@Delimiter, @List + @Delimiter, Number) - Number)))
    FROM (SELECT ROW_NUMBER() OVER (ORDER BY s1.[object_id])
        FROM sys.all_objects AS s1 CROSS APPLY sys.all_objects) AS n(Number)
    WHERE Number <= CONVERT(INT, LEN(@List))
        AND SUBSTRING(@Delimiter + @List, Number, 1) = @Delimiter
    ) AS y);
GO

Tôi đã thảo luận về một số người khác ở đây, tại đây và một cách tiếp cận tốt hơn là tách ra ngay từ đầu ở đây.

Bây giờ bạn có thể ngoại suy đơn giản bằng cách:

SELECT s.[message-id], f.Item
  FROM dbo.SourceData AS s
  CROSS APPLY dbo.SplitStrings(s.[recipient-address], ';') as f;

Ngoài ra, tôi đề nghị không đặt dấu gạch ngang trong tên cột. Có nghĩa là bạn luôn phải đặt chúng trong [square brackets] .