Tạo Menu Truy cập với Điều khiển Chế độ xem Dạng cây

Trình đơn Dự án Microsoft Access, khi hoàn thành với Điều khiển Chế độ xem Dạng cây, sẽ giống như Hình bên dưới.

Hình ảnh ở trên hiển thị Tùy chọn thứ ba của Nhóm Báo cáo Báo cáo Tùy chỉnh được chọn và đánh dấu, với Biểu mẫu thông số bộ lọc báo cáo mở, chồng lên Màn hình menu, cho đầu vào của Người dùng.

Trước khi đi vào vấn đề đó, trong Bài học của tuần trước, chúng ta đã học cách sắp xếp các mục liên quan theo thứ tự phân cấp, bằng cách sử dụng Microsoft Tree View Control, dựa trên Mẫu bảng dữ liệu.

Tuần trước, tôi đã lưu ý rằng các mục có liên quan trong dữ liệu của điều khiển Chế độ xem dạng cây không nhất thiết phải ở cạnh nhau. Sau đó, bạn sẽ rõ hơn về cách cập nhật Relative Khóa của nút con, bất kể vị trí thực của các bản ghi trong Bảng, nhưng dựa trên mối quan hệ với ID nút mẹ của nó.

Đây là Bảng Dữ liệu mà chúng tôi đã sử dụng và đã hoàn thành bài tập của tuần trước:

Bạn có thể thêm danh sách các mục sau vào cuối bảng trên và cập nhật các giá trị trường ParentID của chúng để màn hình TreeView trông giống như hình ảnh mẫu được cung cấp bên dưới không:

Bản ghi mới cho Bảng bản ghi mục có liên quan đến trường :

Trường Văn bản.
Trường Số.
Trường Ngày / Giờ.
Trường siêu kết nối.

Biểu mẫu Kiểm soát liên quan:

Hộp văn bản.
Các nút lệnh.
Hộp Tổ hợp.
Hộp Danh sách.

Báo cáo Kiểm soát liên quan:

Hộp văn bản.
Nhãn.
Biểu đồ Đồ thị.

Gán Giá trị ParentID cho các mục này để Màn hình Chế độ xem dạng cây trông giống như Hình ảnh sau:

Bây giờ, chúng ta sẽ tiến hành tạo Menu Dự án MS-Access và tìm hiểu những gì cần thiết để tạo một Menu. Dưới đây là một Hình ảnh Menu đơn giản:

Đây là một Menu đơn giản chỉ có ba nhóm tùy chọn:Biểu mẫu, Chế độ xem Báo cáo và Macro.

Trong Biểu mẫu Nhóm hai tùy chọn được đưa ra, tùy chọn đầu tiên hiển thị bản ghi bảng Menu điều khiển Chế độ xem cây. Tùy chọn thứ hai hiển thị các bản ghi giống nhau ở chế độ biểu mẫu liên tục.

Tùy chọn đầu tiên trong Chế độ xem báo cáo hiển thị Báo cáo về sản phẩm Danh mục bản ghi, từ Bảng danh mục của NorthWind.accdb cơ sở dữ liệu.

Tùy chọn thứ hai hiển thị Báo cáo Giá-Danh sách Sản phẩm.

Thứ ba tùy chọn mở Tham số Biểu mẫu để Người dùng có thể đặt Tối thiểu imum và Max imum phạm vi giá trị Danh sách-Giá, để Lọc dữ liệu cho Báo cáo Giá-Danh sách Sản phẩm.

Trong Quy trình macro Nhóm, cả hai tùy chọn đều chạy Macro1 và Macro2 tương ứng và hiển thị các thông báo khác nhau.

Chúng tôi cần một Bảng Menu với các bản ghi tùy chọn ở trên với một số trường bổ sung, bên cạnh các trường dữ liệu ID duy nhất, Mô tả và ParentID thông thường của TreeView. Hình ảnh Bảng Menu được đưa ra dưới đây:

Tạo Bảng với cấu trúc trên, thêm các bản ghi ở trên và lưu với tên Trình đơn . ID trường là AutoNumber, PID, và Loại các trường là trường Số, các trường khác là Trường Văn bản.

Chúng ta đã quen thuộc với ba Trường dữ liệu đầu tiên: ID duy nhất , Mô tả, và ParentID Lĩnh vực. Ở đây, tôi đã rút ngắn tên trường ParentID thành PID .

Chúng tôi cần thêm bốn trường trong Bảng Menu, một trường Loại cho loại đối tượng Mã và ba trường Biểu mẫu , Báo cáo, và Macro .

Loại Trường chứa Mã số loại đối tượng truy cập để xác định Tùy chọn mà người dùng đã nhấp vào.

Trường Biểu mẫu dành cho Tên biểu mẫu, Mã loại đối tượng 1,
Trường Báo cáo chứa Tên Báo cáo, Mã loại đối tượng 2,
Trường Macro dành cho Tên Macro, mã loại đối tượng 3.

Lưu ý: Tất cả các tên đối tượng có thể được đặt trong một Cột. Chúng tôi đã sử dụng các trường riêng biệt chỉ để làm rõ ràng. Nếu bạn làm điều đó thì hãy thực hiện các thay đổi trong Mã VBA, bất cứ nơi nào nó tham chiếu đến các tên trường khác nhau.

Dựa trên các số mã, chúng tôi có thể chọn Tên đối tượng, từ các trường tương ứng của chúng và gọi DoCmd.Openform hoặc Docmd.OpenReport hoặc Docmd.RunMacro để thực hiện hành động trên Nhấp chuột vào nút con.

Bây giờ, chúng ta cần lưu trữ Mã loại và Tên đối tượng trên các nút con. Chúng tôi sẽ tiếp tục chủ đề đó khi chúng tôi bắt đầu Thêm các nút vào điều khiển Chế độ xem dạng cây.

Chúng tôi cần thêm hai Bảng dữ liệu cho các Biểu mẫu và Báo cáo mẫu. Danh mục Bảng và Sản phẩm Các bảng, từ NorthWind.accdb Cơ sở dữ liệu mẫu. Để tiết kiệm thời gian của bạn, tôi đã đính kèm Cơ sở dữ liệu Demo với tất cả các Đối tượng và Chương trình ở cuối Trang này để Tải xuống và dùng thử.

Tạo hai Biểu mẫu bằng Bảng Trình đơn với tên Nhập dữ liệu và một Biểu mẫu khác Chế độ xem dữ liệu liên tục Chế độ biểu mẫu.

Tạo hai báo cáo, một báo cáo trên Bảng Danh mục với tên báo cáo: Danh mục, một báo cáo khác trên Bảng sản phẩm với tên Danh sách sản phẩm . Thêm một Nhãn dài kiểm soát bên dưới tiêu đề chính trên Báo cáo danh sách sản phẩm và thay đổi Giá trị thuộc tính tên thành Phạm vi .

Tạo một biểu mẫu nhỏ với hai TextBox không liên kết và đổi tên Giá trị thuộc tính của chúng thành Min & Tối đa, như thiết kế được đưa ra dưới đây:

Thêm hai nút lệnh như hình trên. Thay đổi Chú thích Giá trị thuộc tính của nút đầu tiên để Open Repor t và Tên Giá trị thuộc tính thành cmdReport .

Thay đổi chú thích của nút lệnh thứ hai thành Hủy và Tên Giá trị thuộc tính thành cmdCancel .

Hiển thị Mô-đun mã của Biểu mẫu. Sao chép và Dán Mã sau vào Mô-đun Biểu mẫu và lưu Biểu mẫu:

Private Sub cmdOpen_Click()
Dim mn, mx, fltr As String
mn = Nz(Me![Min], 0)
mx = Nz(Me![Max], 9999)
If (mn + mx) > 0 Then
    fltr = "[List Price] > " & mn & " And " & "[List Price] <= " & mx
    DoCmd.OpenReport "Products Listing", acViewReport, , fltr, , fltr
Else
    DoCmd.OpenReport "Products Listing", acViewReport
End If

End Sub

Private Sub cmdCancel_Click()
DoCmd.Close
End Sub

Khi Người dùng đặt Phạm vi giá trị bằng cách nhập Phạm vi giá niêm yết tối thiểu và tối đa trong các Hộp văn bản tương ứng của họ, Chuỗi tiêu chí Bộ lọc Báo cáo sẽ được tạo. Bộ lọc Báo cáo Giá trị chuỗi được chuyển đến Danh sách sản phẩm Báo cáo dưới dạng lệnh Mở Báo cáo Tham số. Giá trị Chuỗi bộ lọc cũng được chuyển dưới dạng OpenArgs (Đối số mở) Tham số.

Tham số Bộ lọc lọc Dữ liệu báo cáo, dựa trên Tiêu chí, được chỉ định trong trường Tối thiểu &Tối đa và giá trị đối số mở được sao chép vào Phạm vi Chú thích nhãn khi Báo cáo đang mở.

Sao chép và dán mã sau vào Danh sách sản phẩm Mô-đun VBA của Báo cáo:

Private Sub Report_Open(Cancel As Integer)
    DoCmd.Close acForm, "Parameter"
    Me.Range.Caption = Nz(Me.OpenArgs, "")
End Sub

Tạo một biểu mẫu mới, với tên frmMenu, và thêm Điều khiển Microsoft TreeView từ Danh sách điều khiển Activex. Thay đổi kích thước của Điều khiển như được hiển thị trong Dạng xem Thiết kế bên dưới:
Thay đổi tên của Điều khiển chế độ xem dạng cây thành TreeView0 trong Trang thuộc tính thông thường.
Thêm Nút lệnh bên dưới điều khiển Chế độ xem dạng cây. Thay đổi Tên của nó Giá trị thuộc tính thành cmdExit và Chú thích Giá trị thuộc tính để Thoát .
Nhấp chuột phải vào Điều khiển Chế độ xem dạng cây và đánh dấu TreeCtrl_Object và chọn Thuộc tính để hiển thị Trang thuộc tính.
Thay đổi các Giá trị Thuộc tính sau như được cung cấp bên dưới:

Style =7 (tvwTreeLinesPlusMinusPictureText)
Kiểu dòng =1 (tvwRootLines)
LabelEdit =1 (tvwManual)

Tuần trước, chúng tôi đã thay đổi hai Giá trị tài sản đầu tiên. Khi LabelEdit Giá trị mặc định của thuộc tính là 0 - tvwAutomatic, Nhấp vào Node hai lần (không phải nhấp đúp), Node-Text sẽ chuyển sang Chế độ Chỉnh sửa và bạn có thể thay đổi Văn bản. Nhưng nó sẽ không cập nhật trực tiếp trường nguồn dữ liệu. Bằng cách thay đổi nó thành 1 - tvwManual sẽ ngăn nó chuyển sang chế độ chỉnh sửa.

Chúng ta có thể thay đổi điều này thông qua Mã bằng cách thêm các dòng sau trong Thủ tục sự kiện Form_Load ():

With Me.TreeView0.Object
    .Style = tvwTreelinesPlusMinusPictureText
    .LineStyle = tvwRootLines	
    .LabelEdit = tvwManual
End With

Tuần trước, chúng tôi đã sử dụng Form_Load () Thủ tục sự kiện để đọc các giá trị của nút Chế độ xem dạng cây để tạo nút cấp độ gốc và nút con. Chúng tôi cũng cần Quy trình tương tự ở đây với vài dòng Mã bổ sung.

Bên cạnh đó, chúng ta cần bẫy Node_Click () Sự kiện của các nút để kiểm tra tùy chọn mà Người dùng đã chọn.

Sao chép và Dán Mã VBA sau vào Mô-đun Biểu mẫu và lưu Biểu mẫu.

Option Compare Database
Option Explicit

Dim tv As MSComctlLib.TreeView
Const KeyPrfx As String = "X"

Private Sub Form_Load()
Dim db As Database
Dim rst As Recordset
Dim nodKey As String
Dim PKey As String
Dim strText As String
Dim strSQL As String

Dim tmpNod As MSComctlLib.Node
Dim Typ As Variant

Set tv = Me.TreeView0.Object
tv.Nodes.Clear
‘Change the TreeView Control Properties
With tv
    .Style = tvwTreelinesPlusMinusPictureText
    .LineStyle = tvwRootLines
    .LabelEdit = tvwManual
    .Font.Name = "Verdana"
End With
strSQL = "SELECT ID, Desc, PID, Type,Macro,Form,Report FROM Menu;"

Set db = CurrentDb
Set rst = db.OpenRecordset(strSQL, dbOpenDynaset)

Do While Not rst.EOF And Not rst.BOF
    If Nz(rst!PID, "") = "" Then
        nodKey = KeyPrfx & CStr(rst!ID)
        strText = rst!Desc
      Set tmpNod = tv.Nodes.Add(, , nodKey, strText)
      
      'Root-Level Node Description in Bold letters
      With tmpNod
        .Bold = True
      End With
    Else
        PKey = KeyPrfx & CStr(rst!PID)
        nodKey = KeyPrfx & CStr(rst!ID)
        strText = rst!Desc
        Set tmpNod = tv.Nodes.Add(PKey, tvwChild, nodKey, strText)
     
     'Check for the presense of Type Code
        If Nz(rst!Type, 0) > 0 Then
            Typ = rst!Type
            Select Case Typ
                Case 1 'save type Code & Form Name in Node Tag Property
                    tmpNod.Tag = Typ & rst!Form
                Case 2 'save type Code & Report Name in Node Tag Property
                    tmpNod.Tag = Typ & rst!Report
                Case 3 'save type Code & Macro Name in Node Tag Property
                    tmpNod.Tag = Typ & rst!Macro
            End Select
        End If
        
    End If
    rst.MoveNext
Loop
rst.Close

Set rst = Nothing
Set db = Nothing

End Sub

Private Sub cmdExit_Click()
If MsgBox("Close Menu Form? ", vbYesNo, "cmdExit_Click()") = vbYes Then
    DoCmd.Close
End If
End Sub

Private Sub TreeView0_NodeClick(ByVal Node As Object)
Dim varTag, typeid As Integer
Dim objName As String, nodOn as MSComctlLib.Node

If Node.Expanded = False Then
    Node.Expanded = True
Else
    Node.Expanded = False
End If
‘Reset the earlier lighlight to normal
For Each nodOn In tv.Nodes
    nodOn.BackColor = vbWhite
    nodOn.ForeColor = vbBlack
Next
‘changes BackColor to light Blue and ForeColor White
tv.Nodes.Item(Node.Key).BackColor = RGB(0, 143, 255)
tv.Nodes.Item(Node.Key).ForeColor = vbWhite
‘—Highlight code ends-
varTag = Nz(Node.Tag, "")
If Len(varTag) > 0 Then
    typeid = Val(varTag)
    objName = Mid(varTag, 2)
End If

Select Case typeid
    Case 1
        DoCmd.OpenForm objName, acNormal
    Case 2
        DoCmd.OpenReport objName, acViewPreview
    Case 3
        DoCmd.RunMacro objName
End Select
End Sub

Trên Vùng Khai báo Toàn cục của Mô-đun, Đối tượng Dạng xem Cây được khai báo. Một biến hằng số KeyPrfx được khai báo với giá trị “X”.

Form_Load () Quy trình sự kiện của Bài viết tuần trước, chúng tôi đã sửa đổi với Bộ luật bổ sung. Tôi đã nhận xét về phân đoạn Mã mới để đưa ra dấu hiệu về những gì nó làm nhưng sẽ giải thích những gì nó làm.

Thủ tục khai báo Cơ sở dữ liệu, Tập bản ghi và bốn Biến chuỗi. Hai dòng Tiếp theo khai báo Đối tượng nút tạm thời: tmpNod và Typ Biến thể Các biến được khai báo.

Tiếp theo, Đối tượng TreeView tv được chỉ định với TreeView0 Đối tượng trên Biểu mẫu. Các nút hiện có của TreeView0, nếu có, sẽ bị xóa bằng câu lệnh: tv.Nodes.Clear , để chuẩn bị tải lại tất cả các Nút.

Chúng tôi đã triển khai Mã sau để sửa đổi Thuộc tính của điều khiển Chế độ xem dạng cây thông qua Mã, thay vì qua Trang thuộc tính.

With tv
    .Style = tvwTreelinesPlusMinusPictureText
    .LineStyle = tvwRootLines
    .LabelEdit = tvwManual
    .Font.Name = "Verdana"
End With

Phông chữ Chế độ xem dạng cây được thay đổi thành Verdana. Bên cạnh đó, chúng tôi sẽ cung cấp thêm một số chức năng như mở rộng hoặc thu gọn tất cả các Nhóm Menu chỉ bằng một cú nhấp chuột, thay vì mở rộng hoặc thu gọn thủ công hết nhóm này đến nhóm khác.

Chuỗi SQL mới được sửa đổi để thêm Loại trường, Biểu mẫu, Báo cáo và Trường Macro mới từ Bảng Menu.

Bản ghi đầu tiên của Bảng menu được kiểm tra sự hiện diện của bất kỳ giá trị nào trong PID , nếu nó trống thì nó là bản ghi Node cấp gốc. Nó được thêm vào Đối tượng Chế độ xem dạng cây làm Nút cấp độ gốc và tham chiếu của nó được lưu trong tmpNod Đối tượng.

Node có một số thuộc tính như Forecolor, Bold, và một số khác trong số đó, chúng tôi đã sử dụng Bold Thuộc tính và được chỉ định Đúng để đặt Cấp gốc Nút trông khác với các Nút con của nó.

Nếu nó không phải là mục nhập Root Node thì nó có giá trị PID, chương trình sẽ lấy Khác mệnh đề và bản ghi được thêm vào dưới dạng Nút con. Tại đây, chúng tôi kiểm tra Loại giá trị trường. Nếu nó chứa một trong ba giá trị 1, 2, hoặc 3 thì chúng ta phải lấy giá trị từ Biểu mẫu, Báo cáo hoặc Tên Macro cùng với Mã loại đó và kết hợp chúng với nhau (như ”1Data Entry” , “Danh sách 2 danh mục” v.v.) và lưu nó trong Thẻ Thuộc tính của các nút con. Chúng tôi đã quen thuộc với Thuộc tính thẻ trong điều khiển Access, như Hộp văn bản, Nhãn, Nút lệnh và các thuộc tính khác, nhưng chúng tôi hiếm khi sử dụng nó.

cmdExit_Click () Quy trình đóng Biểu mẫu menu nếu phản hồi từ Người dùng là khẳng định.

Khi người dùng nhấp vào Nút con, giá trị chúng tôi đã lưu trong Thẻ của nó Tài sản phải được trích xuất và kiểm tra để xác định những gì cần làm tiếp theo. Đối với điều này, chúng tôi cần một TreeView0_NodeClick () Thủ tục sự kiện.

Private Sub TreeView0_NodeClick(ByVal Node As Object)
Dim varTag, typeid As Integer
Dim objName As String, nodOn as MSComctlLib.Node

If Node.Expanded = False Then
    Node.Expanded = True
Else
    Node.Expanded = False
End If 
‘Reset the earlier lighlight to normal
For Each nodOn In tv.Nodes
  nodOn.BackColor = vbWhite 
  nodOn.ForeColor = vbBlack
Next nodOn

‘changes BackColor to light Blue and ForeColor White
    tv.Nodes.Item(Node.Key).BackColor = RGB(0, 143, 255)
    tv.Nodes.Item(Node.Key).ForeColor = vbWhite
‘—Highlight code ends-

varTag = Nz(Node.Tag, "")
If Len(varTag) > 0 Then
    typeid = Val(varTag)
    objName = Mid(varTag, 2)
End If

Select Case typeid
    Case 1
        DoCmd.OpenForm objName, acNormal
    Case 2
        DoCmd.OpenReport objName, acViewPreview
    Case 3
        DoCmd.RunMacro objName
End Select
End Sub

Thủ tục sự kiện Click () nhận được Tham chiếu của nút được nhấp dưới dạng Tham số trong đối tượng Node . Khi bắt đầu thủ tục này, chúng ta đã khai báo một vài Biến.

Vài dòng tiếp theo kiểm tra xem Nút được nhấp ở trạng thái mở rộng hay thu gọn.

Thông thường, để mở rộng một Nút, để hiển thị các Nút con ẩn của nó, chúng ta nhấp vào nút + (dấu cộng) ở bên trái của một Node hoặc nhấp đúp vào chính Node đó. Nhấp đúp vào nút một lần nữa hoặc nhấp vào - (biểu tượng dấu trừ) sẽ ẩn các nút con.

Với đoạn Mã sau, chúng ta có thể mở rộng hoặc thu gọn các Nút con chỉ bằng một cú nhấp chuột:

If Node.Expanded = False Then
    Node.Expanded = True
Else
    Node.Expanded = False
End If

Sáu dòng thực thi tiếp theo đảm bảo rằng Nút nhận được Nhấp chuột vẫn được đánh dấu.

‘Reset the earlier Highlight to Normal
For Each nodOn In tv.Nodes
  nodOn.BackColor = vbWhite 
  nodOn.ForeColor = vbBlack
Next nodOn
‘Changes BackColor to light Blue and ForeColor White
    tv.Nodes.Item(Node.Key).BackColor = RGB(0, 143, 255)
    tv.Nodes.Item(Node.Key).ForeColor = vbWhite
‘—Highlight code ends-

Tiếp theo, giá trị Thuộc tính thẻ được đọc trong varTag Biến đổi. Nếu nó không trống thì giá trị được chia thành hai phần. Giá trị Numeric được trích xuất và lưu trong Typid và phần Tên đối tượng được lưu trong biến objName .

Tùy thuộc vào giá trị trong biến Typid, Docmd được thực thi để mở Biểu mẫu, Báo cáo hoặc Chạy Macro.

Chúng tôi sẽ thêm hai nút lệnh nữa trên đầu Menu. Một để mở rộng tất cả các Nút bằng một lần Nhấp và nút thứ hai để thu gọn tất cả các Nút.

Thêm hai Nút Lệnh nữa ở khu vực trên cùng của Điều khiển Chế độ xem Cây như được hiển thị trên thiết kế bên dưới.
Thay đổi Tên Giá trị thuộc tính của Nút lệnh bên trái thành cmdExpand và Chú thích để Mở rộng tất cả .
Tương tự, thay đổi Tên của Nút lệnh bên phải Thuộc tính thành cmdCollapse và Chú thích để Thu gọn tất cả.
Sao chép và Dán Mã VBA sau bên dưới Mã hiện có trong frmMenu Mô-đun biểu mẫu và lưu biểu mẫu.

Private Sub cmdExpand_Click()
Dim Nodexp As MSComctlLib.Node

For Each Nodexp In tv.Nodes
    If Nodexp.Expanded = False Then
        Nodexp.Expanded = True
    End If
Next Nodexp
End Sub


Private Sub cmdCollapse_Click()
Dim Nodexp As MSComctlLib.Node

For Each Nodexp In tv.Nodes
    If Nodexp.Expanded = True Then
        Nodexp.Expanded = False
    End If
Next Nodexp
End Sub

Ở đầu cmdExpand_Click () Sự kiện, chúng tôi đã khai báo một đối tượng Tree View Node NodExp. Các Đối với. . . Tiếp theo vòng lặp thực hiện một Node tại một thời điểm và kiểm tra xem nó có ở dạng mở rộng hay không. Nếu không thì Đã mở rộng Giá trị thuộc tính được đặt thành True .

Tương tự, cmdCollapse_Click () Sự kiện thực hiện một kiểm tra tương tự và nếu sự kiện ở trạng thái mở rộng thì giá trị Thuộc tính được mở rộng được đặt thành Sai.

Tất cả các Nút của Chế độ xem dạng cây đầy đủ có thể được mở rộng và làm cho tất cả các Nút con của chúng hiển thị cùng một lúc hoặc tất cả các Nút con được giữ ẩn ngoại trừ các Nút cấp Gốc.

Hy vọng bạn thích tạo Menu mới cho Dự án của mình. Nếu bạn thực hiện từng bước nhiệm vụ thiết kế thì Menu của bạn sẽ trông giống như Hình ảnh Menu đã hoàn thành ở trên cùng.

Trong Năm 2007, tôi đã thiết kế Menu trong một trong những Dự án của mình, dành cho Hệ thống Hợp đồng Dịch vụ Xe cộ, sử dụng Điều khiển Tab với một số Trang. Mỗi Trang có 10 Tùy chọn trở lên và để làm cho mỗi Trang lần lượt xuất hiện tại cùng một khu vực khi người dùng nhấp vào các Nút lệnh được xếp ở hai bên của Menu. nút bên trái.

Nhấp để Phóng to

Bạn có thể tìm thấy Bài viết về Thiết kế Menu với Điều khiển Tab trên Liên kết này:https://www.msaccesstips.com/2007/06/control-screen-menu-design.html

MODULE LỚP

Mô-đun lớp MS-Access và VBA
Mảng và đối tượng lớp VBA MS-Access
Lớp cơ sở MS-Access và các đối tượng có nguồn gốc
VBA-Base Class và Derived Object-2
Lớp cơ sở và các biến thể đối tượng có nguồn gốc
Tập bản ghi MS-Access và Mô-đun lớp
Truy cập mô-đun lớp và các lớp gói
Chức năng của lớp Wrapper